Thread obsoleto Screen con visual basic6

[3n1gm1st4]

ciao ragazzi oggi andiamo alla creazione di un piccolo programmino per poter
far screnn in visual basic 6

allora apriamo visual basic 6
dopo di che inseriamo 6 commandbutton
e una picture box
ed inseriamo il seguente codice :

Option Explicit

Private Sub Form_Load()
Picture1.AutoSize = True
End Sub

Private Sub Command1_Click() 'Cattura lo schermo intero
Set Picture1.Picture = CaptureScreen()
End Sub

Private Sub Command2_Click() 'Cattura tutto il form (inclusa la barra del titolo e i bordi)
Set Picture1.Picture = CaptureForm(Me)
End Sub

Private Sub Command3_Click() ' Cattura solo la "client area" del form (esclusa la barra del titolo e i bordi)
Set Picture1.Picture = CaptureClient(Me)
End Sub

Private Sub Command4_Click() ' Cattura la finestra attiva
Dim EndTime As Date

MsgBox "Dopo due secondi da quando verrà chiuso questo messaggio" & vbCrLf & _
"verrà catturata la finestra che sarà attiva in quel momento", vbInformation, Me.Caption

' Avvia il temporizzatore.
EndTime = DateAdd("s", 2, Now)
Do Until Now > EndTime 'attende 2 secondi
DoEvents
Loop

Set Picture1.Picture = CaptureActiveWindow()

' Ritorna il focus al form
Me.SetFocus
End Sub

Private Sub Command5_Click() ' Stampa l'immagine catturata nel PictureBox
Dim risp As Integer
risp = MsgBox("Vuoi stampare l'immagine catturata?", vbQuestion + vbYesNo, Me.Caption)
If risp = vbNo Then Exit Sub
PrintPictureToFitPage Printer, Picture1.Picture
Printer.EndDoc
End Sub

Private Sub Command7_Click() 'salva l'immagine catturata in un file .bmp

CD1.FileName = vbNullString
CD1.DefaultExt = "bmp"
CD1.Filter = "Bitmap|*.bmp"
CD1.ShowSave

If CD1.FileName <> vbNullString Then
SavePicture Picture1.Image, CD1.FileName ' Salva l'immagine in un file .bmp
End If

End Sub

Private Sub Command6_Click() ' Cancella il contenuto della PictureBox
Set Picture1.Picture = Nothing
End Sub

dopo di chè inseriamo un modulo e inseriamo il codice :

Option Explicit
Option Base 0

Private Declare Function CreateCompatibleDC Lib "GDI32" (ByVal hDC As Long) As Long
Private Declare Function CreateCompatibleBitmap Lib "GDI32" (ByVal hDC As Long, ByVal nWidth As Long, ByVal nHeight As Long) As Long
Private Declare Function GetDeviceCaps Lib "GDI32" (ByVal hDC As Long, ByVal iCapabilitiy As Long) As Long
Private Declare Function GetSystemPaletteEntries Lib "GDI32" (ByVal hDC As Long, ByVal wStartIndex As Long, _
ByVal wNumEntries As Long, lpPaletteEntries As PALETTEENTRY) As Long

Private Declare Function CreatePalette Lib "GDI32" (lpLogPalette As LOGPALETTE) As Long
Private Declare Function SelectObject Lib "GDI32" (ByVal hDC As Long, ByVal hObject As Long) As Long
Private Declare Function BitBlt Lib "GDI32" (ByVal hDCDest As Long, ByVal XDest As Long, _
ByVal YDest As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hDCSrc As Long, _
ByVal XSrc As Long, ByVal YSrc As Long, ByVal dwRop As Long) As Long

Private Declare Function DeleteDC Lib "GDI32" (ByVal hDC As Long) As Long
Private Declare Function GetForegroundWindow Lib "USER32" () As Long
Private Declare Function SelectPalette Lib "GDI32" (ByVal hDC As Long, ByVal hPalette As Long, _
ByVal bForceBackground As Long) As Long

Private Declare Function RealizePalette Lib "GDI32" (ByVal hDC As Long) As Long
Private Declare Function GetWindowDC Lib "USER32" (ByVal hWnd As Long) As Long
Private Declare Function GetDC Lib "USER32" (ByVal hWnd As Long) As Long
Private Declare Function GetWindowRect Lib "USER32" (ByVal hWnd As Long, lpRect As RECT) As Long
Private Declare Function ReleaseDC Lib "USER32" (ByVal hWnd As Long, ByVal hDC As Long) As Long
Private Declare Function GetDesktopWindow Lib "USER32" () As Long
Private Declare Function OleCreatePictureIndirect Lib "olepro32.dll" (PicDesc As PicBmp, RefIID As GUID, _
ByVal fPictureOwnsHandle As Long, IPic As IPicture) As Long

Private Type PALETTEENTRY
peRed As Byte
peGreen As Byte
peBlue As Byte
peFlags As Byte
End Type

Private Type LOGPALETTE
palVersion As Integer
palNumEntries As Integer
palPalEntry(255) As PALETTEENTRY ' Enough for 256 colors.
End Type

Private Type GUID
Data1 As Long
Data2 As Integer
Data3 As Integer
Data4(7) As Byte
End Type

Private Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type


Private Type PicBmp
Size As Long
Type As Long
hBmp As Long
hPal As Long
Reserved As Long
End Type

Private Const RASTERCAPS As Long = 38
Private Const RC_PALETTE As Long = &H100
Private Const SIZEPALETTE As Long = 104

Public Function CreateBitmapPicture(ByVal hBmp As Long, ByVal hPal As Long) As Picture

' - Creates a bitmap type Picture object from a bitmap and palette.
' hBmp - Handle to a bitmap.
' hPal - Handle to a Palette.
' - Can be null if the bitmap doesn't use a palette.
' Returns - Returns a Picture object containing the bitmap.


Dim r As Long
Dim Pic As PicBmp
Dim IPic As IPicture ' IPicture requires a reference to "Standard OLE Types."

Dim IID_IDispatch As GUID
With IID_IDispatch ' Fill in with IDispatch Interface ID
.Data1 = &H20400
.Data4(0) = &HC0
.Data4(7) = &H46
End With

' Fill Pic with necessary parts.
With Pic
.Size = Len(Pic) ' Length of structure.
.Type = vbPicTypeBitmap ' Type of Picture (bitmap).
.hBmp = hBmp ' Handle to bitmap.
.hPal = hPal ' Handle to palette (may be null).
End With

' Create Picture object.
r = OleCreatePictureIndirect(Pic, IID_IDispatch, 1, IPic)

' Return the new Picture object.
Set CreateBitmapPicture = IPic
End Function

Public Function CaptureWindow(ByVal hWndSrc As Long, ByVal Client As Boolean, ByVal LeftSrc As Long, _
ByVal TopSrc As Long, ByVal WidthSrc As Long, ByVal HeightSrc As Long) As Picture
' - Captures any portion of a window.
' hWndSrc = Handle to the window to be captured.
' Client = If True CaptureWindow captures from the client area of the window
' - If False CaptureWindow captures from the entire window.
' LeftSrc, TopSrc, WidthSrc, HeightSrc
' - Specify the portion of the window to capture (dimensions need to be specified in pixels)
' - Returns a Picture object containing a bitmap of the specified portion of the window that was captured.

Dim hDCMemory As Long
Dim hBmp As Long
Dim hBmpPrev As Long
Dim r As Long
Dim hDCSrc As Long
Dim hPal As Long
Dim hPalPrev As Long
Dim RasterCapsScrn As Long
Dim HasPaletteScrn As Long
Dim PaletteSizeScrn As Long
Dim LogPal As LOGPALETTE

' Depending on the value of Client get the proper device context
If Client Then
hDCSrc = GetDC(hWndSrc) ' Get device context for client area
Else
hDCSrc = GetWindowDC(hWndSrc) ' Get device context for entire window
End If

' Create a memory device context for the copy process.
hDCMemory = CreateCompatibleDC(hDCSrc)
' Create a bitmap and place it in the memory DC.
hBmp = CreateCompatibleBitmap(hDCSrc, WidthSrc, HeightSrc)
hBmpPrev = SelectObject(hDCMemory, hBmp)

' Get screen properties.
RasterCapsScrn = GetDeviceCaps(hDCSrc, RASTERCAPS) ' Raster capabilities
HasPaletteScrn = RasterCapsScrn And RC_PALETTE ' Palette support
PaletteSizeScrn = GetDeviceCaps(hDCSrc, SIZEPALETTE) ' Size of palette

' If the screen has a palette make a copy and realize it
If HasPaletteScrn And (PaletteSizeScrn = 256) Then
' Create a copy of the system palette.
LogPal.palVersion = &H300
LogPal.palNumEntries = 256
r = GetSystemPaletteEntries(hDCSrc, 0, 256, _
LogPal.palPalEntry(0))
hPal = CreatePalette(LogPal)
' Select the new palette into the memory DC and realize it
hPalPrev = SelectPalette(hDCMemory, hPal, 0)
r = RealizePalette(hDCMemory)
End If

' Copy the on-screen image into the memory DC.
r = BitBlt(hDCMemory, 0, 0, WidthSrc, HeightSrc, hDCSrc, _
LeftSrc, TopSrc, vbSrcCopy)

' Remove the new copy of the on-screen image.
hBmp = SelectObject(hDCMemory, hBmpPrev)

' If the screen has a palette get back the palette that was
' selected in previously.
If HasPaletteScrn And (PaletteSizeScrn = 256) Then
hPal = SelectPalette(hDCMemory, hPalPrev, 0)
End If

' Release the device context resources back to the system.
r = DeleteDC(hDCMemory)
r = ReleaseDC(hWndSrc, hDCSrc)

' Call CreateBitmapPicture to create a picture object from the bitmap and palette handles.
'Then return the resulting picture object.
Set CaptureWindow = CreateBitmapPicture(hBmp, hPal)
End Function

Public Function CaptureScreen() As Picture
' - Captures the entire screen.
' Returns - Returns a Picture object containing a bitmap of the screen.

Dim hWndScreen As Long

hWndScreen = GetDesktopWindow() ' Get a handle to the desktop window.

' Call CaptureWindow to capture the entire desktop give the handle and return the resulting Picture object.
Set CaptureScreen = CaptureWindow(hWndScreen, False, 0, 0, _
Screen.Width \ Screen.TwipsPerPixelX, Screen.Height \ Screen.TwipsPerPixelY)

End Function

Public Function CaptureForm(frmSrc As Form) As Picture ' Captures an entire form including title bar and border.
' frmSrc = The Form object to capture.
' Returns = Returns a Picture object containing a bitmap of the entire form.

' Call CaptureWindow to capture the entire form given its window handle and then return the resulting Picture object.
Set CaptureForm = CaptureWindow(frmSrc.hWnd, False, 0, 0, _
frmSrc.ScaleX(frmSrc.Width, vbTwips, vbPixels), frmSrc.ScaleY(frmSrc.Height, vbTwips, vbPixels))
End Function

Public Function CaptureClient(frmSrc As Form) As Picture 'Captures the client area of a form.

' frmSrc = The Form object to capture.
' Returns = returns a Picture object containing a bitmap of the form's client area.

'Call CaptureWindow to capture the client area of the form given its window handle and return the resulting Picture object.
Set CaptureClient = CaptureWindow(frmSrc.hWnd, True, 0, 0, _
frmSrc.ScaleX(frmSrc.ScaleWidth, frmSrc.ScaleMode, vbPixels), frmSrc.ScaleY(frmSrc.ScaleHeight, frmSrc.ScaleMode, vbPixels))
End Function

Public Function CaptureActiveWindow() As Picture ' CaptureActiveWindow (captures the currently active window on the screen)
' - Returns a Picture object containing a bitmap of the active window.

Dim hWndActive As Long
Dim r As Long
Dim RectActive As RECT

hWndActive = GetForegroundWindow() 'Get a handle to the active/foreground window.

r = GetWindowRect(hWndActive, RectActive) 'Get the dimensions of the window.


' Call CaptureWindow to capture the active window given its handle and return the Resulting Picture object.
Set CaptureActiveWindow = CaptureWindow(hWndActive, False, 0, 0, _
RectActive.Right - RectActive.Left, RectActive.Bottom - RectActive.Top)
End Function

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
Public Sub PrintPictureToFitPage(Prn As Printer, Pic As Picture) 'PrintPictureToFitPage
' - Prints a Picture object as big as possible.
' Prn = Destination Printer object
' Pic = Source Picture object

Const vbHiMetric As Integer = 8
Dim PicRatio As Double
Dim PrnWidth As Double
Dim PrnHeight As Double
Dim PrnRatio As Double
Dim PrnPicWidth As Double
Dim PrnPicHeight As Double

' Determine if picture should be printed in landscape or portrait and set the orientation.
If Pic.Height >= Pic.Width Then
Prn.Orientation = vbPRORPortrait ' Taller than wide.
Else
Prn.Orientation = vbPRORLandscape ' Wider than tall.
End If

' Calculate device independent Width-to-Height ratio for picture.
PicRatio = Pic.Width / Pic.Height

' Calculate the dimentions of the printable area in HiMetric.
PrnWidth = Prn.ScaleX(Prn.ScaleWidth, Prn.ScaleMode, vbHiMetric)
PrnHeight = Prn.ScaleY(Prn.ScaleHeight, Prn.ScaleMode, vbHiMetric)
' Calculate device independent Width to Height ratio for printer.
PrnRatio = PrnWidth / PrnHeight

' Scale the output to the printable area.
If PicRatio >= PrnRatio Then
' Scale picture to fit full width of printable area.
PrnPicWidth = Prn.ScaleX(PrnWidth, vbHiMetric, Prn.ScaleMode)
PrnPicHeight = Prn.ScaleY(PrnWidth / PicRatio, vbHiMetric, Prn.ScaleMode)
Else
' Scale picture to fit full height of printable area.
PrnPicHeight = Prn.ScaleY(PrnHeight, vbHiMetric, Prn.ScaleMode)
PrnPicWidth = Prn.ScaleX(PrnHeight * PicRatio, vbHiMetric, Prn.ScaleMode)
End If

Prn.PaintPicture Pic, 0, 0, PrnPicWidth, PrnPicHeight 'Print the picture using the PaintPicture method.

End Sub

spero di esservi stato utile x qualsiasi informazione basta chiedere
ciao:bye:

 

[R3tr0s]

ma l'hai fatto tu? metti la fonte da dove lo hai preso

 

[FireFox]

Perfavore, Entra oppure Registrati per vedere i Link!

 

[3n1gm1st4]

no l'autore è stato mauro rossi
e io ho deciso di proppore il codice sorgente